***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Oct 27, 2021                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJD16P06A   D   G   S
*****param & model definition***
.model  dmos  pmos(
+    l = 1e-6		  w = 1e-6		level = 3
+  vto = -2.29		 kp = 12.1)
.model  dds   d(
+   is = 1.712e-11	  n = 1.125		   rs = 1.428e-2
+   eg = 0.8 	      trs1 = -2.300e-2
+   ikf = 9.275e-1)
.model  dbody d(
+   is = 1.712e-11	  n = 1.125		   rs = 1.428e-2
+  cjo = 1.882e-10	  m = 3.393e-1		   vj = 8.236e-1
+   bv = 66		ibv = 250e-6		 tbv1 = 4.379e-4		tt = 25n)
.model  inter  pmos(
+  vto = 0		 kp = 10		level = 1)
.model  dgd    d(
+  cjo = 4.081e-10	  m = 5.973e-1		   vj = 1.247)
.param
+  cgs = 1.602e-09	cgd = 3.945e-10
+   rd = 1.500e-3	ra = 1.300e-2		  trd = 8.800e-2
*****function & circuit*****
rg	  G  1t   1
cgs	 1t   3   {cgs}
egv	  3  2t   table   {v(S, 1t)}
+((0   , 0   ),
+ (0.5 , 0.5 ),
+ (1   , 1   ),
+ (1.5 , 1.5 ),
+ (2   , 2   ),
+ (2.5 , 2.5 ),
+ (2.75, 2.75),
+ (3   , 3.  ),
+ (4   , 4   ),
+ (4.5 , 4.38),
+ (5   , 4.66),
+ (6   , 4.95),
+ (7   , 5.2 ),
+ (8   , 5.4 ),
+ (10  , 5.8 ),
+ (20  , 6   ),
+ (22  , 6   ))
egt	  1  2t   value = {1.107e-3*limit(v(2t,3),-3,0)*limit((temp-25),-80,125)}
mmain	  2   1   3   3   dmos
rd	  D   4   {rd}    tc = {trd}
dds	  4   3   dds
dbody	  D   3   dbody
ra	  4   2   {ra}
rs	  3   5   1e-4
ls	  5   S   0.001n
m1       1t   8   6   6   inter
e1        8   6   4   1t  2
cgd	  7   4   {cgd}
rcgd      7   4   10meg
dgd       4   6   dgd
rdgd      4   6   10meg
m2        7   9  1t  1t   inter
e2        9  1t   4  1t   -2
.ends
*$
